home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / pc / files / dsp / a56_10sh.z / a56_10sh / examples / effects / flange.a56 < prev    next >
Text File  |  1996-06-25  |  3KB  |  156 lines
  1. ;***************************************************************
  2. ;
  3. ;    Stereo Flange for the DSP56001 processor
  4. ;    Developed by Quinn Jensen (jensenq@npd.novell.com)
  5. ;
  6. ;***************************************************************
  7. include 'tdsg.basic.a56'
  8.  
  9. dot
  10.     org    x:$20
  11.  
  12. ; Sample rate              32.5500 kc         
  13. ; 
  14. ; Delay time (1-12)         6.0000 ms         
  15. ; Depth (1-10)             10.0000
  16. ; Speed (1-10)              1.0000
  17. ; Regen (1-10)              9.0000
  18. ; 
  19. ; max depth +/-             6.0000 ms         
  20. ; min delay                 1.0000 ms         
  21. ; max delay                12.0000 ms         
  22. ; 1/2 cycle period          4.5100 s          
  23. ; samples per 1/2 cyc  146800.5000
  24. ; time delta/samp           0.0817 us         
  25. ; offset samp/samp          0.0027
  26. ; 
  27.   doff_i equ                               -33
  28.   ddeltaf equ                     0.0026607539
  29.   dspeed_i equ                          146800
  30.   dregen equ                      0.8888888889
  31.  
  32. delay    equ    $2000
  33. dmax    equ    4096        ;125 ms
  34. doff    dc    doff_i        ;current delay distance
  35.     org    y:doff
  36.     dc    0
  37.  
  38.     org    x:doff+1
  39. ddelta    dc    0        ;
  40.     org    y:ddelta
  41.     dc    ddeltaf
  42.  
  43.     org    x:ddelta+1
  44.  
  45. dspeed    dc    dspeed_i
  46. dtoggle    dc    0        ;
  47. delayout
  48.     dc    0
  49.  
  50.     org    y:$0
  51.  
  52.     org    p:dot        ;go back to P-space
  53. ;
  54. ; non-interrupt code
  55. ;
  56.  
  57. flange_init
  58.     move    #delay,r1            ;delay line input
  59.      movec    #dmax-1,m1            ;
  60.     move    #doff_i,n1            ;distance to output
  61.     rts
  62.  
  63. ;
  64. ; fs = 32.552083 kHz
  65. ;
  66.  
  67. flange_comp
  68.     jsr    <saveregs
  69. ;
  70. ;    output and input mix
  71. ;
  72.     clr    a    #.4375,x1        ;clr a, get input scale
  73.     clr    b    #.5,y1            ;clr b, get output scaler
  74.  
  75.     move        x:<delayout,y0        ;get delay out
  76.  
  77.     move        #.70,x0            ;do regen term
  78.     macr    x0,y0,a
  79.     macr    x0,y0,a
  80.  
  81.     move        #.75,x0
  82.  
  83.     macr    y0,x0,b    x:<in_l,x0        ;b = .5 * delay, x0=in_l
  84.     macr    x0,y1,b        b,y0           ;b += .5 * in_l, y0=b
  85.     macr    x0,x1,a b,x:<out_l        ;a += x1 * in_l, L = b
  86.     move            y0,b        ;b = -y0
  87.     neg    b    x:<in_r,x0        ;x0 = in_r
  88.     macr    x0,y1,b                ;b += .5 * in_r
  89.     macr    x0,x1,a    b,x:<out_r        ;R = b, a += x1 * in_r
  90. ;
  91. ;    delay line in
  92. ;
  93.     move        a,x:(r1)+
  94. ;
  95. ;    delay line length modulation
  96. ;
  97.     move        l:<doff,a        ;a = current offset
  98.     move        l:<ddelta,x        ;x = current delta
  99.     add    x,a
  100.     move        a,l:<doff        ;new offset = a + x
  101.     move        a1,n1
  102.  
  103.     move        x1,b            ;save delta for later use
  104.  
  105. ; smoothly transition between delay-line offsets by
  106. ; interpolating the current sample with the previous or next
  107. ; one depending on whether the delay is currently getting longer or
  108. ; shorter.  Otherwise, an obnoxious click results when the offset snaps
  109. ; to the next integral value.
  110.  
  111.     move            y:<doff,a    ;compute |frac(doff)|
  112.     lsr    a    #$800000,x0
  113.     or    x0,a    #.5,x1
  114.     move        a1,x0
  115.     mpy    -x0,x1,a
  116.     tst    b        a,y0        ;y0 = 0.5 * |frac(doff)|
  117.     jpl    shorter                ;on positive delta, the
  118.                         ;delay is shortening
  119.  
  120.     move        (r1)-            ;get previous sample
  121.     move        x:(r1+n1),x0
  122.     mpy    y0,x0,a    #.5,b            ;scale
  123.     sub    y0,b    (r1)+            ;compute scale for cur sample
  124.     move            b,y0
  125.     move        x:(r1+n1),x0        ;get cur sample
  126.     mac    x0,y0,a                ;scale and sum
  127.     jmp    endpan
  128.  
  129. shorter
  130.     move        x:(r1+n1),x0        ;get cur sample
  131.     mpy    y0,x0,a    #.5,b            ;scale
  132.     sub    y0,b    (r1)+            ;compute scale for next sample
  133.     move            b,y0
  134.     move        x:(r1+n1),x0        ;get next sample
  135.     mac    x0,y0,a    (r1)-            ;scale and sum
  136. endpan
  137.     move        a,x:<delayout        ;store resulting output
  138.  
  139. ; update the triangle wave modulation
  140.  
  141.     move        x:<dtoggle,a        ;decrement toggle count
  142.     move        #>1,x0
  143.     sub    x0,a
  144.     move        a,x:<dtoggle
  145.     jgt    notogg                ;time to toggle?
  146.     move        x:<dspeed,x0        ;yes, negate delta and reset
  147.     move        l:<ddelta,a
  148.     neg    a    x0,x:<dtoggle
  149.     move        a,l:<ddelta
  150. notogg
  151. bypass
  152.     jsr    <restregs
  153.     rts
  154.  
  155.     end
  156.